mirror of
https://github.com/gensokyo-zone/infrastructure.git
synced 2026-02-09 12:29:19 -08:00
chore(minecraft): module cleanup
This commit is contained in:
arcnmx
parent
e07f689dec
commit
7a7057492c
9 changed files with 426 additions and 207 deletions
238
modules/nixos/minecraft/bedrock.nix
Normal file
238
modules/nixos/minecraft/bedrock.nix
Normal file
|
|
@ -0,0 +1,238 @@
|
|||
{
|
||||
config,
|
||||
gensokyo-zone,
|
||||
lib,
|
||||
pkgs,
|
||||
...
|
||||
}: let
|
||||
# see https://gist.github.com/datakurre/cfdf627fb23ed8ff62bb7b3520b92674
|
||||
inherit (gensokyo-zone.lib) mapOptionDefaults;
|
||||
inherit (lib.options) mkOption mkPackageOption;
|
||||
inherit (lib.modules) mkIf mkMerge mkOptionDefault;
|
||||
inherit (lib.attrsets) filterAttrs mapAttrsToList;
|
||||
inherit (lib.lists) optional;
|
||||
inherit (lib.meta) getExe;
|
||||
inherit (config.lib.minecraft) mkAllowPlayerType mkPackType writeServerProperties writeAllowList writePermissions writePacks;
|
||||
cfg = config.services.minecraft-bedrock-server;
|
||||
in {
|
||||
options.services.minecraft-bedrock-server = with lib.types; {
|
||||
enable = mkOption {
|
||||
type = bool;
|
||||
default = false;
|
||||
description = ''
|
||||
If enabled, start a Minecraft Bedrock Server. The server
|
||||
data will be loaded from and saved to
|
||||
<option>services.minecraft-bedrock-server.dataDir</option>.
|
||||
'';
|
||||
};
|
||||
|
||||
dataDir = mkOption {
|
||||
type = path;
|
||||
default = "/var/lib/minecraft-bedrock";
|
||||
description = ''
|
||||
Directory to store Minecraft Bedrock database and other state/data files.
|
||||
'';
|
||||
};
|
||||
|
||||
serverProperties = mkOption {
|
||||
type = attrsOf (oneOf [bool int str float]);
|
||||
example = literalExample ''
|
||||
{
|
||||
server-name = "Dedicated Server";
|
||||
gamemode = "survival";
|
||||
difficulty = "easy";
|
||||
allow-cheats = false;
|
||||
max-players = 10;
|
||||
online-mode = false;
|
||||
white-list = false;
|
||||
server-port = 19132;
|
||||
server-portv6 = 19133;
|
||||
view-distance = 32;
|
||||
tick-distance = 4;
|
||||
player-idle-timeout = 30;
|
||||
max-threads = 8;
|
||||
level-name = "Bedrock level";
|
||||
level-seed = "";
|
||||
default-player-permission-level = "member";
|
||||
texturepack-required = false;
|
||||
content-log-file-enabled = false;
|
||||
compression-threshold = 1;
|
||||
server-authoritative-movement = "server-auth";
|
||||
player-movement-score-threshold = 20;
|
||||
player-movement-distance-threshold = 0.3;
|
||||
player-movement-duration-threshold-in-ms = 500;
|
||||
correct-player-movement = false;
|
||||
}
|
||||
'';
|
||||
description = ''
|
||||
Minecraft Bedrock server properties for the server.properties file.
|
||||
'';
|
||||
};
|
||||
|
||||
package =
|
||||
mkPackageOption pkgs "minecraft-bedrock-server" {}
|
||||
// {
|
||||
description = "Version of minecraft-bedrock-server to run.";
|
||||
};
|
||||
|
||||
openFirewall = mkOption {
|
||||
type = bool;
|
||||
default = false;
|
||||
};
|
||||
|
||||
user = mkOption {
|
||||
type = str;
|
||||
default = "minecraft-bedrock";
|
||||
};
|
||||
group = mkOption {
|
||||
type = str;
|
||||
default = cfg.user;
|
||||
};
|
||||
|
||||
allowPlayers = mkOption {
|
||||
type = nullOr (attrsOf (mkAllowPlayerType {}));
|
||||
default = null;
|
||||
};
|
||||
|
||||
allowList = mkOption {
|
||||
type = nullOr path;
|
||||
};
|
||||
|
||||
permissions = mkOption {
|
||||
type = nullOr path;
|
||||
};
|
||||
|
||||
packs = mkOption {
|
||||
type = attrsOf (mkPackType {});
|
||||
default = {};
|
||||
};
|
||||
};
|
||||
|
||||
config = let
|
||||
confService.services.minecraft-bedrock-server = {
|
||||
serverProperties = mapOptionDefaults {
|
||||
server-name = "Dedicated Server";
|
||||
gamemode = "survival";
|
||||
difficulty = "easy";
|
||||
allow-cheats = false;
|
||||
max-players = 10;
|
||||
online-mode = false;
|
||||
allow-list = cfg.allowList != null;
|
||||
server-port = 19132;
|
||||
server-portv6 = 19133;
|
||||
view-distance = 32;
|
||||
tick-distance = 4;
|
||||
player-idle-timeout = 30;
|
||||
max-threads = 8;
|
||||
level-name = "Bedrock level";
|
||||
level-seed = "";
|
||||
default-player-permission-level = "member";
|
||||
texturepack-required = false;
|
||||
content-log-file-enabled = false;
|
||||
compression-threshold = 1;
|
||||
server-authoritative-movement = "server-auth";
|
||||
player-movement-score-threshold = 20;
|
||||
player-movement-distance-threshold = 0.3;
|
||||
player-movement-duration-threshold-in-ms = 500;
|
||||
correct-player-movement = false;
|
||||
};
|
||||
allowList = mkOptionDefault (
|
||||
if cfg.allowPlayers != null
|
||||
then writeAllowList cfg.allowPlayers
|
||||
else null
|
||||
);
|
||||
permissions = mkOptionDefault (
|
||||
if cfg.allowPlayers != null
|
||||
then writePermissions cfg.allowPlayers
|
||||
else null
|
||||
);
|
||||
};
|
||||
conf.users.users.${cfg.user} = {
|
||||
inherit (cfg) group;
|
||||
description = "Minecraft server service user";
|
||||
home = cfg.dataDir;
|
||||
createHome = true;
|
||||
isSystemUser = true;
|
||||
};
|
||||
conf.users.groups.${cfg.group} = {};
|
||||
|
||||
conf.systemd.services.minecraft-bedrock-server = {
|
||||
description = "Minecraft Bedrock Server Service";
|
||||
wantedBy = ["multi-user.target"];
|
||||
after = ["network.target"];
|
||||
|
||||
serviceConfig = {
|
||||
BindReadOnlyPaths = let
|
||||
packageResources = map (subpath: "${cfg.package}/var/lib/minecraft-bedrock/${subpath}:${cfg.dataDir}/${subpath}") ([
|
||||
"definitions/attachables"
|
||||
"definitions/biomes"
|
||||
"definitions/feature_rules"
|
||||
"definitions/features"
|
||||
"definitions/persona"
|
||||
"definitions/sdl_layouts"
|
||||
"definitions/spawn_groups"
|
||||
"resource_packs/vanilla"
|
||||
"resource_packs/chemistry"
|
||||
"config/default"
|
||||
"bedrock_server_symbols.debug"
|
||||
"env-vars"
|
||||
]
|
||||
++ optional (cfg.permissions == null) "permissions.json");
|
||||
mkWorldPacks = type: let
|
||||
enabledPacks = filterAttrs (_: pack: pack.enable && pack.packType == type) cfg.packs;
|
||||
packsJsonPath = writePacks { inherit type; } enabledPacks;
|
||||
in
|
||||
mkIf (enabledPacks != {}) [
|
||||
"${packsJsonPath}:${cfg.dataDir}/worlds/${cfg.serverProperties.level-name}/${packsJsonPath.name}"
|
||||
];
|
||||
mapWorldPacks = packs: let
|
||||
enabledPacks = filterAttrs (_: pack: pack.enable && pack.package != null) packs;
|
||||
mapPackPath = _: pack: let
|
||||
subDir = "${pack.packType}/${pack.packDir}";
|
||||
in "${pack.package}/${cfg.package.dataDir}/${subDir}:${cfg.dataDir}/${subDir}";
|
||||
in
|
||||
mapAttrsToList mapPackPath enabledPacks;
|
||||
packsPaths = mkMerge [
|
||||
(mkWorldPacks "behavior_packs")
|
||||
(mkWorldPacks "resource_packs")
|
||||
(mapWorldPacks cfg.packs)
|
||||
];
|
||||
in
|
||||
mkMerge [
|
||||
packageResources
|
||||
(mkIf (cfg.allowList != null) ["${cfg.allowList}:${cfg.dataDir}/allowlist.json"])
|
||||
(mkIf (cfg.permissions != null) ["${cfg.permissions}:${cfg.dataDir}/permissions.json"])
|
||||
(mkIf (cfg.packs != {}) packsPaths)
|
||||
];
|
||||
ExecStart = [
|
||||
"${getExe cfg.package}"
|
||||
];
|
||||
Restart = "always";
|
||||
User = cfg.user;
|
||||
WorkingDirectory = cfg.dataDir;
|
||||
LogFilterPatterns = [
|
||||
"~.*minecraft:trial_chambers/chamber/end"
|
||||
"~Running AutoCompaction"
|
||||
];
|
||||
};
|
||||
|
||||
preStart = ''
|
||||
mkdir -p behavior_packs
|
||||
ln -sf ${cfg.package}/var/lib/minecraft-bedrock/behavior_packs/* behavior_packs/
|
||||
cp -f ${writeServerProperties cfg.serverProperties} server.properties
|
||||
chmod +w server.properties
|
||||
'';
|
||||
};
|
||||
|
||||
conf.networking.firewall = let
|
||||
ports = [cfg.serverProperties.server-port cfg.serverProperties.server-portv6];
|
||||
in
|
||||
mkIf cfg.openFirewall {
|
||||
allowedUDPPorts = ports;
|
||||
};
|
||||
in
|
||||
mkMerge [
|
||||
confService
|
||||
(mkIf cfg.enable conf)
|
||||
];
|
||||
}
|
||||
221
modules/nixos/minecraft/common.nix
Normal file
221
modules/nixos/minecraft/common.nix
Normal file
|
|
@ -0,0 +1,221 @@
|
|||
let
|
||||
allowListModule = {
|
||||
config,
|
||||
name,
|
||||
gensokyo-zone,
|
||||
lib,
|
||||
...
|
||||
}: let
|
||||
inherit (gensokyo-zone.Std) UInt;
|
||||
inherit (gensokyo-zone.lib) json;
|
||||
inherit (lib.options) mkOption;
|
||||
inherit (lib.modules) mkOptionDefault;
|
||||
inherit (builtins) typeOf;
|
||||
in {
|
||||
options = with lib.types; {
|
||||
name = mkOption {
|
||||
type = str;
|
||||
default = name;
|
||||
};
|
||||
xuid = mkOption {
|
||||
type = nullOr (oneOf [int str]);
|
||||
};
|
||||
uuid = mkOption {
|
||||
type = nullOr str;
|
||||
};
|
||||
permission = mkOption {
|
||||
type = enum ["visitor" "member" "operator"];
|
||||
default = "member";
|
||||
};
|
||||
permissionLevel = mkOption {
|
||||
type = ints.between 0 4;
|
||||
description = "1=mod, 2=gm, 3=admin, 4=owner";
|
||||
default = 0;
|
||||
};
|
||||
settings = mkOption {
|
||||
type = json.types.attrs;
|
||||
};
|
||||
whitelistSettings = mkOption {
|
||||
type = json.types.attrs;
|
||||
};
|
||||
permissionSettings = mkOption {
|
||||
type = json.types.attrs;
|
||||
};
|
||||
opsSettings = mkOption {
|
||||
type = json.types.attrs;
|
||||
};
|
||||
};
|
||||
config = let
|
||||
xuid =
|
||||
{
|
||||
string = toString (UInt.FromHex config.xuid);
|
||||
int = toString config.xuid;
|
||||
}
|
||||
.${typeOf config.xuid};
|
||||
in {
|
||||
settings = {
|
||||
name = mkOptionDefault config.name;
|
||||
xuid = mkOptionDefault xuid;
|
||||
# TODO: ignoresPlayerLimit = true/false
|
||||
};
|
||||
whitelistSettings = {
|
||||
name = mkOptionDefault config.name;
|
||||
uuid = mkOptionDefault config.uuid;
|
||||
};
|
||||
permissionSettings = {
|
||||
xuid = mkOptionDefault xuid;
|
||||
permission = mkOptionDefault config.permission;
|
||||
};
|
||||
opsSettings = {
|
||||
name = mkOptionDefault config.name;
|
||||
uuid = mkOptionDefault config.uuid;
|
||||
level = mkOptionDefault config.permissionLevel;
|
||||
bypassesPlayerLimit = mkOptionDefault true;
|
||||
};
|
||||
};
|
||||
};
|
||||
packModule = {
|
||||
config,
|
||||
lib,
|
||||
...
|
||||
}: let
|
||||
inherit (lib.options) mkOption mkEnableOption;
|
||||
inherit (lib.modules) mkIf mkOptionDefault;
|
||||
inherit (lib.strings) splitString;
|
||||
inherit (builtins) typeOf;
|
||||
in {
|
||||
options = with lib.types; {
|
||||
enable =
|
||||
mkEnableOption "pack"
|
||||
// {
|
||||
default = true;
|
||||
};
|
||||
package = mkOption {
|
||||
type = nullOr package;
|
||||
default = null;
|
||||
};
|
||||
packDir = mkOption {
|
||||
type = str;
|
||||
};
|
||||
packType = mkOption {
|
||||
type = enum ["resource_packs" "behavior_packs"];
|
||||
};
|
||||
packId = mkOption {
|
||||
type = str;
|
||||
};
|
||||
version = mkOption {
|
||||
type = oneOf [str (listOf str)];
|
||||
};
|
||||
settings = mkOption {
|
||||
type = attrsOf (oneOf [str (listOf str)]);
|
||||
};
|
||||
};
|
||||
config = {
|
||||
packId = mkIf (config.package != null && config.package ? minecraft-bedrock.pack.pack_id) (
|
||||
mkOptionDefault
|
||||
config.package.minecraft-bedrock.pack.pack_id
|
||||
);
|
||||
packType = mkIf (config.package != null && config.package ? minecraft-bedrock.pack.type) (
|
||||
mkOptionDefault
|
||||
config.package.minecraft-bedrock.pack.type
|
||||
);
|
||||
version = mkIf (config.package != null && config.package ? minecraft-bedrock.pack.version) (
|
||||
mkOptionDefault
|
||||
config.package.minecraft-bedrock.pack.version
|
||||
);
|
||||
packDir = mkIf (config.package != null && config.package ? minecraft-bedrock.pack.dir) (
|
||||
mkOptionDefault
|
||||
config.package.minecraft-bedrock.pack.dir
|
||||
);
|
||||
settings = {
|
||||
pack_id = mkOptionDefault config.packId;
|
||||
version =
|
||||
mkOptionDefault
|
||||
{
|
||||
string = splitString "." config.version;
|
||||
list = config.version;
|
||||
}
|
||||
.${typeOf config.version};
|
||||
};
|
||||
};
|
||||
};
|
||||
in
|
||||
{
|
||||
config,
|
||||
gensokyo-zone,
|
||||
lib,
|
||||
pkgs,
|
||||
...
|
||||
}: let
|
||||
inherit (lib.attrsets) mapAttrsToList filterAttrs;
|
||||
inherit (lib.strings) concatStringsSep;
|
||||
inherit (lib.trivial) boolToString;
|
||||
inherit (builtins) toJSON;
|
||||
inherit (config.lib) minecraft;
|
||||
in {
|
||||
config.lib.minecraft = {
|
||||
inherit allowListModule packModule;
|
||||
mkAllowPlayerType = {
|
||||
modules ? [],
|
||||
specialArgs ? {},
|
||||
}:
|
||||
lib.types.submoduleWith {
|
||||
modules = modules ++ [minecraft.allowListModule];
|
||||
specialArgs =
|
||||
{
|
||||
inherit gensokyo-zone;
|
||||
nixosConfig = config;
|
||||
}
|
||||
// specialArgs;
|
||||
};
|
||||
writeAllowList = allowPlayers: let
|
||||
allowList = mapAttrsToList (_: allow: allow.settings) allowPlayers;
|
||||
in
|
||||
pkgs.writeText "allowlist.json" (toJSON allowList);
|
||||
writeWhiteList = allowPlayers: let
|
||||
allowList = mapAttrsToList (_: allow: allow.whitelistSettings) allowPlayers;
|
||||
in
|
||||
pkgs.writeText "whitelist.json" (toJSON allowList);
|
||||
writePermissions = allowPlayers: let
|
||||
permissions = mapAttrsToList (_: allow: allow.permissionSettings) allowPlayers;
|
||||
in
|
||||
pkgs.writeText "permissions.json" (toJSON permissions);
|
||||
writeOps = allowPlayers: let
|
||||
ops = filterAttrs (_: player: player.permissionLevel > 0) allowPlayers;
|
||||
permissions = mapAttrsToList (_: allow: allow.opsSettings) ops;
|
||||
in
|
||||
pkgs.writeText "ops.json" (toJSON permissions);
|
||||
mkPackType = {
|
||||
modules ? [],
|
||||
specialArgs ? {},
|
||||
}:
|
||||
lib.types.submoduleWith {
|
||||
modules = modules ++ [minecraft.packModule];
|
||||
specialArgs =
|
||||
{
|
||||
inherit gensokyo-zone;
|
||||
nixosConfig = config;
|
||||
}
|
||||
// specialArgs;
|
||||
};
|
||||
writePacks = {type}: packs: let
|
||||
packsSettings = mapAttrsToList (_: pack: pack.settings) packs;
|
||||
in
|
||||
pkgs.writeText "world_${type}.json" (toJSON packsSettings);
|
||||
writeServerProperty = let
|
||||
cfgToString = v:
|
||||
if builtins.isBool v
|
||||
then boolToString v
|
||||
else toString v;
|
||||
in
|
||||
n: v: "${n}=${cfgToString v}";
|
||||
writeServerProperties = serverProperties: let
|
||||
inherit (config.lib.minecraft) writeServerProperty;
|
||||
lines = mapAttrsToList writeServerProperty serverProperties;
|
||||
in
|
||||
pkgs.writeText "server.properties" ''
|
||||
# server.properties managed by NixOS configuration
|
||||
${concatStringsSep "\n" lines}
|
||||
'';
|
||||
};
|
||||
}
|
||||
172
modules/nixos/minecraft/katsink.nix
Normal file
172
modules/nixos/minecraft/katsink.nix
Normal file
|
|
@ -0,0 +1,172 @@
|
|||
{
|
||||
config,
|
||||
gensokyo-zone,
|
||||
lib,
|
||||
pkgs,
|
||||
...
|
||||
}: let
|
||||
inherit (gensokyo-zone.lib) mapOptionDefaults;
|
||||
inherit (lib.options) mkOption mkEnableOption mkPackageOption;
|
||||
inherit (lib.modules) mkIf mkMerge mkAfter mkOptionDefault;
|
||||
inherit (lib.strings) escapeShellArgs;
|
||||
inherit (lib.meta) getExe;
|
||||
inherit (config.lib.minecraft) mkAllowPlayerType writeWhiteList writeOps;
|
||||
cfg = config.services.minecraft-katsink-server;
|
||||
in {
|
||||
options.services.minecraft-katsink-server = with lib.types; {
|
||||
enable = mkEnableOption "kat-kitchen-sink";
|
||||
|
||||
openFirewall = mkOption {
|
||||
type = bool;
|
||||
default = false;
|
||||
};
|
||||
port = mkOption {
|
||||
type = port;
|
||||
default = 25565;
|
||||
};
|
||||
|
||||
jre.package = mkPackageOption pkgs "jre" {};
|
||||
|
||||
dataDir = mkOption {
|
||||
type = path;
|
||||
default = "/var/lib/minecraft-katsink";
|
||||
description = ''
|
||||
Directory to store Minecraft database and other state/data files.
|
||||
'';
|
||||
};
|
||||
|
||||
argsFiles = mkOption {
|
||||
type = listOf str;
|
||||
default = ["user_jvm_args.txt"];
|
||||
};
|
||||
|
||||
jvmOpts = mkOption {
|
||||
type = listOf str;
|
||||
default = [];
|
||||
example = ["-Xmx4G"];
|
||||
};
|
||||
|
||||
user = mkOption {
|
||||
type = str;
|
||||
default = "minecraft-bedrock";
|
||||
};
|
||||
group = mkOption {
|
||||
type = str;
|
||||
default = cfg.user;
|
||||
};
|
||||
|
||||
serverProperties = mkOption {
|
||||
type = attrsOf (oneOf [bool int str float]);
|
||||
};
|
||||
|
||||
allowPlayers = mkOption {
|
||||
type = nullOr (attrsOf (mkAllowPlayerType {}));
|
||||
default = null;
|
||||
};
|
||||
};
|
||||
|
||||
config = let
|
||||
confService.services.minecraft-katsink-server = {
|
||||
serverProperties = mapOptionDefaults {
|
||||
};
|
||||
};
|
||||
conf.users = mkIf (cfg.user == "minecraft-bedrock") {
|
||||
users.${cfg.user} = {
|
||||
inherit (cfg) group;
|
||||
description = "Minecraft server service user";
|
||||
home = cfg.dataDir;
|
||||
createHome = true;
|
||||
isSystemUser = true;
|
||||
};
|
||||
groups.${cfg.group} = {};
|
||||
};
|
||||
|
||||
conf.systemd.services.minecraft-katsink-server = let
|
||||
execStartArgs =
|
||||
map (argsFile: "@${argsFile}") cfg.argsFiles
|
||||
++ cfg.jvmOpts;
|
||||
execStop = pkgs.writeShellScriptBin "minecraft-katsink-stop" ''
|
||||
echo /stop > ${config.systemd.sockets.minecraft-katsink-server.socketConfig.ListenFIFO}
|
||||
|
||||
# Wait for the PID of the minecraft server to disappear before
|
||||
# returning, so systemd doesn't attempt to SIGKILL it.
|
||||
while kill -0 "$1" 2> /dev/null; do
|
||||
sleep 1s
|
||||
done
|
||||
'';
|
||||
in {
|
||||
description = "Minecraft Kat Kitchen Server";
|
||||
wantedBy = ["multi-user.target"];
|
||||
requires = ["minecraft-katsink-server.socket"];
|
||||
after = ["network.target" "minecraft-katsink-server.socket"];
|
||||
|
||||
restartTriggers = [
|
||||
cfg.dataDir
|
||||
cfg.jvmOpts
|
||||
cfg.argsFiles
|
||||
];
|
||||
|
||||
path = [cfg.jre.package];
|
||||
script = mkAfter ''
|
||||
exec java ${escapeShellArgs execStartArgs}
|
||||
'';
|
||||
|
||||
serviceConfig = {
|
||||
BindReadOnlyPaths = mkIf (cfg.allowPlayers != null) [
|
||||
"${writeWhiteList cfg.allowPlayers}:${cfg.dataDir}/whitelist.json"
|
||||
"${writeOps cfg.allowPlayers}:${cfg.dataDir}/ops.json"
|
||||
];
|
||||
ExecStop = "${getExe execStop} $MAINPID";
|
||||
Restart = "always";
|
||||
User = cfg.user;
|
||||
WorkingDirectory = cfg.dataDir;
|
||||
RuntimeDirectory = "minecraft-katsink";
|
||||
|
||||
StandardInput = "socket";
|
||||
StandardOutput = "journal";
|
||||
StandardError = "journal";
|
||||
|
||||
# Hardening
|
||||
CapabilityBoundingSet = [""];
|
||||
DeviceAllow = [""];
|
||||
LockPersonality = true;
|
||||
PrivateDevices = true;
|
||||
PrivateTmp = true;
|
||||
PrivateUsers = true;
|
||||
ProtectClock = true;
|
||||
ProtectControlGroups = true;
|
||||
ProtectHome = true;
|
||||
ProtectHostname = true;
|
||||
ProtectKernelLogs = true;
|
||||
ProtectKernelModules = true;
|
||||
ProtectKernelTunables = true;
|
||||
ProtectProc = "invisible";
|
||||
RestrictAddressFamilies = ["AF_INET" "AF_INET6" "AF_UNIX"];
|
||||
RestrictNamespaces = true;
|
||||
RestrictRealtime = true;
|
||||
RestrictSUIDSGID = true;
|
||||
SystemCallArchitectures = "native";
|
||||
UMask = "0077";
|
||||
};
|
||||
};
|
||||
conf.systemd.sockets.minecraft-katsink-server = {
|
||||
bindsTo = ["minecraft-katsink-server.service"];
|
||||
socketConfig = {
|
||||
ListenFIFO = "/run/minecraft-katsink/stdin";
|
||||
SocketMode = "0660";
|
||||
SocketUser = mkOptionDefault cfg.user;
|
||||
SocketGroup = mkOptionDefault cfg.group;
|
||||
RemoveOnStop = true;
|
||||
FlushPending = true;
|
||||
};
|
||||
};
|
||||
|
||||
conf.networking.firewall = mkIf cfg.openFirewall {
|
||||
allowedUDPPorts = cfg.port;
|
||||
};
|
||||
in
|
||||
mkMerge [
|
||||
confService
|
||||
(mkIf cfg.enable conf)
|
||||
];
|
||||
}
|
||||
Loading…
Add table
Add a link
Reference in a new issue