refactor: get rid of config folder

modules/home/deploy.nix

@@ -0,0 +1,39 @@
+{ config, lib, ... }:
+
+/*
+  This module:
+  * Provides in-scope TF config for home-manager.
+*/
+
+with lib;
+
+let
+  cfg = config.deploy.tf;
+  unmergedValues = types.mkOptionType {
+    name = "unmergedValues";
+    merge = loc: defs: map (def: def.value) defs;
+  };
+in
+{
+
+  options.deploy.tf = mkOption {
+    type = types.submodule {
+      freeformType = types.attrsOf unmergedValues;
+
+      options = {
+        attrs = mkOption {
+          type = types.listOf types.str;
+          default = [ ];
+        };
+        out.set = mkOption { type = types.unspecified; };
+      };
+    };
+
+  };
+  config = {
+    deploy.tf = {
+      attrs = [ "out" "attrs" ];
+      out.set = removeAttrs cfg cfg.attrs;
+    };
+  };
+}

modules/home/disables.nix

@@ -0,0 +1,4 @@
+{ ... }: {
+  disabledModules = [
+  ];
+}

modules/home/displays.nix

@@ -0,0 +1,22 @@
+{ config, lib, nixos, ... }: with lib; {
+  options.hardware.displays = mkOption {
+    type = with types; attrsOf (submodule ({ config, ... }: {
+      options = {
+        pos = mkOption {
+          type = types.str;
+        };
+        res = mkOption {
+          type = types.str;
+        };
+      };
+    }));
+  };
+  config = mkMerge [
+    {
+      hardware.displays = nixos.hardware.displays;
+    }
+    (mkIf config.wayland.windowManager.sway.enable {
+      wayland.windowManager.sway.config.output = config.hardware.displays;
+    })
+  ];
+}

modules/home/firewall.nix

@@ -0,0 +1,54 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let cfg = config.network.firewall;
+in
+{
+  options.network.firewall = {
+    public.tcp.ports = mkOption {
+      type = types.listOf types.port;
+      default = [ ];
+    };
+    public.udp.ports = mkOption {
+      type = types.listOf types.port;
+      default = [ ];
+    };
+    private.tcp.ports = mkOption {
+      type = types.listOf types.port;
+      default = [ ];
+    };
+    private.udp.ports = mkOption {
+      type = types.listOf types.port;
+      default = [ ];
+    };
+
+    public.tcp.ranges = mkOption {
+      type = types.listOf (types.attrsOf types.port);
+      default = [ ];
+    };
+    public.udp.ranges = mkOption {
+      type = types.listOf (types.attrsOf types.port);
+      default = [ ];
+    };
+    private.tcp.ranges = mkOption {
+      type = types.listOf (types.attrsOf types.port);
+      default = [ ];
+    };
+    private.udp.ranges = mkOption {
+      type = types.listOf (types.attrsOf types.port);
+      default = [ ];
+    };
+
+    public.interfaces = mkOption {
+      type = types.listOf types.str;
+      description = "Public firewall interfaces";
+      default = [ ];
+    };
+    private.interfaces = mkOption {
+      type = types.listOf types.str;
+      description = "Private firewall interfaces";
+      default = [ ];
+    };
+  };
+}

modules/home/network.nix

@@ -0,0 +1,77 @@
+{ config, nixos, lib, ... }:
+
+with lib;
+
+{
+  options.network = {
+    enable = mkEnableOption "Use kat's network module?";
+    addresses = mkOption {
+      type = with types; attrsOf (submodule ({ name, ... }: {
+        options = {
+          enable = mkEnableOption "Is the system a part of the ${name} network?";
+          ipv4 = {
+            enable = mkOption {
+              type = types.bool;
+            };
+            address = mkOption {
+              type = types.str;
+            };
+          };
+          ipv6 = {
+            enable = mkOption {
+              type = types.bool;
+            };
+            address = mkOption {
+              type = types.str;
+            };
+          };
+          prefix = mkOption {
+            type = types.nullOr types.str;
+          };
+          domain = mkOption {
+            type = types.nullOr types.str;
+          };
+          out = {
+            identifierList = mkOption {
+              type = types.listOf types.str;
+              default = if config.enable then singleton config.domain ++ config.out.addressList else [ ];
+            };
+            addressList = mkOption {
+              type = types.listOf types.str;
+              default = if config.enable then concatMap (i: optional i.enable i.address) [ config.ipv4 config.ipv6 ] else [ ];
+            };
+          };
+        };
+      }));
+    };
+    tf = {
+      enable = mkEnableOption "Was the system provisioned by terraform?";
+      ipv4_attr = mkOption {
+        type = types.str;
+      };
+      ipv6_attr = mkOption {
+        type = types.str;
+      };
+    };
+    dns = {
+      enable = mkEnableOption "Do you want DNS to be semi-managed through this module?";
+      isRoot = mkEnableOption "Is this system supposed to be the @ for the domain?";
+      email = mkOption {
+        type = types.nullOr types.str;
+      };
+      zone = mkOption {
+        type = types.nullOr types.str;
+      };
+      domain = mkOption {
+        type = types.nullOr types.str;
+      };
+      dynamic = mkEnableOption "Enable Glauca Dynamic DNS Updater";
+    };
+  };
+
+  config = {
+    network.addresses = nixos.network.addresses or {};
+    network.tf = nixos.network.tf or {};
+    network.dns = nixos.network.dns or {};
+  };
+}

modules/home/secrets.nix

@@ -0,0 +1,43 @@
+{ config, nixos, lib, ... }:
+
+with lib;
+
+let
+  secretType = types.submodule ({ name, ... }: {
+    options = {
+      path = mkOption { type = types.str; };
+      field = mkOption {
+        type = types.str;
+        default = "";
+      };
+    };
+  });
+  repoSecretType = types.submodule ({ name, ... }: {
+    options = {
+      source = mkOption {
+        type = types.path;
+      };
+      text = mkOption {
+        type = types.str;
+      };
+    };
+  });
+  cfg = config.kw.secrets;
+in
+{
+  options.kw = {
+    secrets = {
+      variables = mkOption {
+        type = types.attrsOf secretType;
+        default = { };
+      };
+      repo = mkOption {
+        type = types.attrsOf repoSecretType;
+        default = { };
+      };
+    };
+  };
+  config = {
+    kw.secrets.repo = nixos.kw.secrets.repo;
+  };
+}

modules/home/theme.nix

@@ -0,0 +1,158 @@
+{ config, pkgs, lib, ... }:
+
+/*
+  This module:
+  * provides a central way to change the font my system uses.
+*/
+
+with lib;
+
+let cfg = config.kw.theme; in
+{
+  options.kw.theme = {
+    enable = mkEnableOption "kat's theme module";
+    sass = {
+      variables = mkOption {
+        type = types.attrsOf types.str;
+        default = (cfg.base16 // cfg.base16t // {
+          term_font = cfg.font.termName;
+          font = cfg.font.name;
+          font_size = cfg.font.size_css;
+        });
+      };
+      css_style = mkOption {
+        type = types.enum [ "nested" "compressed" "compact" "expanded" ];
+        default = "expanded";
+      };
+    };
+    swaylock = mkEnableOption "use swaylock module";
+    base16 = mkOption {
+      type = types.attrsOf types.str;
+    };
+    base16t = mkOption {
+      type = types.attrsOf types.str;
+    };
+    alpha = mkOption {
+      type = types.float;
+    };
+    font = {
+      name = mkOption {
+        type = types.str;
+        default = "Iosevka SS10";
+      };
+      termName = mkOption {
+        type = types.str;
+        default = "Iosevka Term SS10";
+      };
+      size = mkOption {
+        type = types.float;
+        default = 9.0;
+      };
+      size_css = mkOption {
+        type = types.str;
+        default = "${toString (cfg.font.size + 3)}px";
+      };
+    };
+  };
+  config = mkIf (cfg.enable) {
+    kw.theme = {
+      base16 = lib.mapAttrs' (k: v: lib.nameValuePair k "#${v.hex.rgb}")
+        (lib.filterAttrs (n: _: lib.hasInfix "base" n) config.lib.arc.base16.schemeForAlias.default);
+      base16t = lib.mapAttrs' (k: v: lib.nameValuePair "${k}t" "rgba(${toString v.rgb.r}, ${toString v.rgb.g}, ${toString v.rgb.b}, ${toString cfg.alpha})")
+        (lib.filterAttrs (n: _: lib.hasInfix "base" n) config.lib.arc.base16.schemeForAlias.default);
+      alpha = 0.7;
+    };
+
+    programs.swaylock = mkIf (cfg.swaylock) {
+      enable = true;
+      package = pkgs.swaylock-effects-develop;
+      args = {
+        screenshots = true;
+        daemonize = true;
+        show-failed-attempts = true;
+        indicator = true;
+        indicator-radius = 110;
+        indicator-thickness = 8;
+        font = cfg.font.name;
+        font-size = cfg.font.size_css;
+        clock = true;
+        datestr = "%F";
+        timestr = "%T";
+        effect-blur = "5x2";
+        fade-in = 0.2;
+      };
+      colors = with cfg.base16; {
+        key-hl = base0C;
+        separator = base01;
+        line = base01;
+        line-clear = base01;
+        line-caps-lock = base01;
+        line-ver = base01;
+        line-wrong = base01;
+        ring = base00;
+        ring-clear = base0B;
+        ring-caps-lock = base09;
+        ring-ver = base0D;
+        ring-wrong = base08;
+        inside = base00;
+        inside-clear = base00;
+        inside-caps-lock = base00;
+        inside-ver = base00;
+        inside-wrong = base00;
+        text = base05;
+        text-clear = base05;
+        text-caps-lock = base05;
+        text-ver = base05;
+        text-wrong = base05;
+      };
+    };
+
+    systemd.user.services.swayidle = mkIf (cfg.swaylock) {
+      Unit = {
+        Description = "swayidle";
+        Documentation = [ "man:swayidle(1)" ];
+        PartOf = [ "graphical-session.target" ];
+      };
+      Service = {
+        Type = "simple";
+        ExecStart =
+          let
+            lockCommand = config.programs.swaylock.script;
+          in
+          ''
+            ${pkgs.swayidle}/bin/swayidle -w \
+            timeout 300 '${lockCommand}' \
+            timeout 600 'swaymsg "output * dpms off"' \
+            resume 'swaymsg "output * dpms on"' \
+            before-sleep '${lockCommand}'
+          '';
+        RestartSec = 3;
+        Restart = "always";
+      };
+      Install = { WantedBy = [ "sway-session.target" ]; };
+    };
+
+    lib.kw.sassTemplate = { name, src }:
+      let
+        variables = pkgs.writeText "base-variables.sass" ''
+          ${(concatStringsSep "\n" (mapAttrsToList(var: con: "\$${var}: ${con}") cfg.sass.variables))}
+        '';
+        source = pkgs.callPackage
+          ({ sass, stdenv }: stdenv.mkDerivation {
+            inherit name src variables;
+            nativeBuildInputs = lib.singleton sass;
+            phases = [ "buildPhase" ];
+            buildPhase = ''
+              cat $variables $src > src-mut.sass
+              sass src-mut.sass $out --sourcemap=none --style=${cfg.sass.css_style}
+            '';
+          })
+          { };
+      in
+      {
+        inherit source;
+        text = builtins.readFile source;
+      };
+    _module.args = { inherit (config.lib) kw; };
+  };
+}